home *** CD-ROM | disk | FTP | other *** search
/ Revista CD Expert 8 / Revista CD Expert nº 08 CD1.iso / Utilitarios / Programacao / MS-DOS Interrupt List / inter60f / INT2WHLP.ZIP / INT2WHLP.PAS < prev    next >
Pascal/Delphi Source File  |  1998-11-22  |  51KB  |  1,362 lines
  1. (*
  2.   Interrupt List -> WinHelp converter (c) 1994 by Christian Müller-Planitz
  3.   ------------------------------------------------------------------------
  4.   e-mail address: see CONST "e_mail"
  5.  
  6.  
  7.   The source and the compiled EXE-file can be freely distributed as long as
  8.   no changes are made without my knowledge.
  9.  
  10.   --------------------------------
  11.   Notes:
  12.    The program was tested with INTLIST38 and INTLIST39 and its output
  13.      was successfully compiled with the MS-Help-compiler "HC31.EXE" V3.10.445.
  14.  
  15.    The program needs the file "INTWHLP.DAT" in the 'source' directory.
  16.  
  17.    The program converted all sourcefiles (INTERRUP.* and *.LST) to
  18.      13 RTF files which needed 11MB on my harddrive.
  19.  
  20.    Compiling the RTF-files without compression took 13 minutes in
  21.      a DOS-Window under Win/NT on a 486-50 (if you run it under DOS
  22.      and if you have a fast hardrive cache, it might be faster).
  23.  
  24.    The (uncompressed) compiled HLP-File was approximately 7MB large.
  25.    If you want to create a compressed HLP-file, you have to exchange the
  26.      comments in the generated help-project file ("RB.HPJ"). Compressing
  27.      reduces the size of the HLP-file to 3MB but it takes
  28.      *more* (?? 28MB ??)  space on your harddrive while compiling.
  29.      In order to speed up compiling the compressed file, I've included a
  30.      temporary file ("INTWIN.PH") of the helpcompiler in this archive.
  31.      Copy this file into the directory containing all the RTF files
  32.      before starting the compiler. This file is specific for INTERLIST39, so
  33.      if you want to get maximal compression in future versions, remove it.
  34.  
  35.    After the compilation finishes, you will find the file "INTWIN.HLP".
  36.      Start Windows, create an icon in the program manager and double-click on it.
  37.  
  38.    Version 1.11:
  39.    The compressed INTWIN.HLP file compiled from Ralf Brown's Interrupt List
  40.      release 42 occupies appr. 4.6 MB.
  41.  
  42.   --------------------------------
  43.  
  44.    If you find this program usefull, if it does not work or if you have ideas
  45.    how to expand its functionality, feel fee to write an e-mail to me.
  46.  
  47.    As usual, I do not take any responsibility for possible damages done by
  48.    this program.
  49.  
  50.  
  51.   Two questions and their answers :
  52.   ---------------------------------
  53.    WHY is the HLP-file so large ?
  54.      In contrast to other programs that convert the interrupt list to
  55.      DOS-based hypertext systems, this program generates a large
  56.      index file that allows you to search for keywords.
  57.  
  58.    WHY did I wrote this program in Pascal and not in C ?
  59.      I think Pascal is a pretty nice language for small projects.
  60.      Another reason is the availability of efficient string handling under Pascal.
  61. *)
  62.  
  63. {$A+,B-,D+,E-,F-,I+,L+,N-,O-,R-,S-,V-}
  64. {$M 16384,25000,200000}
  65. (* minimum heap estimate (1994): 60*(6+10)+(30+40)*(43+10)+50*256=16770 *)
  66. (* (average entry size times (number of entries + 10) for FLAGS, CATEGORIES,
  67.    and CATEGORYKEYS entries) or times 256 for titles.
  68.    Each string in the [*ALIASES] sections requires (length of string) + 5.
  69. *)
  70.  
  71. Program INT2WHLP;
  72.  
  73. uses DOS;
  74.  
  75. { Version 1.00 - 1994
  76.   v. 1.01 -
  77.   v. 1.01a - 1994-02-16:
  78.     published with Ralf Brown's Interrupt List release 40.
  79.   v. 1.02 - 1994-04-07:
  80.     Changed program name from RB2HLP/INTWHLP to INT2WHLP.
  81.     Reduced the amount of RTF control codes.
  82.     Introduced program parameter controlled behaviour.
  83.     Improved flexibility by use of constants for parts of the control.
  84.     Changed and added some windows.
  85.     Extended search key facilities.
  86.   v. 1.03 - 1994-04-17:
  87.     Expanded/Compressed index switch.
  88.     Multi columns compressed index.
  89.     Interrupt titles OVERVIEW.LST.
  90.   v. 1.04 - 1994-04-29:
  91.     Configuration file including:
  92.       Program parameters can be defined in the configuration file. Such
  93.         definitions are overriden by program parameters.
  94.       Several WINHELP parameters, like font and size, can be specified.
  95.       Supplementary information "windows" can be included.
  96.       An ALIAS list can be compiled and written to the HPJ file.
  97.       A BUILDTAG list can be copied from the configuration to the HPJ file.
  98.   v. 1.05 - 1994-05-07:
  99.     Reconsidered default directories.
  100.   v. 1.06 - 1994-05-26:
  101.     Cross-references to tables.
  102.   v. 1.07 - 1994-05-29:
  103.     Edited procedure explain.
  104.     Skip "Section" file break sections (from a "--------!-Section--.."
  105.       divider line up to the next divider line).
  106.     Executable code released with Interrupt List release 41.
  107.     (ProgVers erroneously = '1.06').
  108.   v. 1.08 - 1994-07-10:
  109.     Tables as separate topics.
  110.   v. 1.10 - 1994-07-20:
  111.     Interrupt List release number dependent compilation.
  112.     Published with Interrupt List release 42.
  113.   v. 1.11 - 1994-09-20:
  114.     [INTWINCONFIG] section in configuration file.
  115.   v. 1.12 - 1994-11-04:
  116.     Test for long graphics lines in ReadLine().
  117.     Published with Interrupt List release 43.
  118.   v. 1.13 - 1994-12-26:
  119.     Transformation of DOS graphics in ReadLine().
  120.     Check for duplicate keywords (from CATEGORYKEYS) in NewHlpPage().
  121.     Secondary register references as keywords.
  122.     Separate RTF files for interrupts and tables, check for direct/inderect
  123.       references to tables from current interrupt.
  124.   v. 1.14 - 1995-03-07:
  125.     Return errorlevel 1 for warnings and >= 2 for errors.
  126.   v. 1.15 - 1995-05-29:
  127.     Avoid empty topic in the beginning of .RTF files.
  128.         Made more tools-tolerant: RTF files for expanded and compressed
  129.         indexes reversed. It is easier for some tools to digest the very
  130.         long expanded index when it is compiled at a later state so all its
  131.         phrases are already known.
  132.     [BAGGAGE] section handling.
  133.     Expanded list of registered warnings.
  134.     Copyright message and credits window include Bent Lynggaard as
  135.     coauthor.
  136.   v. 1.16 - 1995-07-31:
  137.     Christian's new e-mail address.
  138.   v. 1.17 - 1996-01-25:
  139.     Fixed bug in NewHlpPage (bad search keys for AH = xx + secondary reg.).
  140.         Switch to inhibit long search keys for INT topics (in order to support
  141.         limited capacity in WinHelp 4.0).
  142.   v. 1.18 - 1996-10-05:
  143.     Shortcut from Credits topic to Interrup.1st Contact Info.
  144.         Insert icon interrup.ico if it is available in current, INT2WHLP home,
  145.         or source directory.
  146.         intwin.ph no longer included in package, instead download interNNz.zip.
  147.   v. 1.19 - 1997-07-01:
  148.     Returns warning errorlevel if ProcessFile() fails.
  149.     Fixed bug: failed to convert non-ASCII characters in table headers.
  150.   v. 1.20 - 1997-12-15:
  151.     Bug fix: Failed to print backward reference after file sectioning.
  152.         Option -KT: Tabel search string in separate keyword table.
  153.   v. 1.21 - 1998-03-01:
  154.     Fixed two errors introduced in v. 1.20 bugfix: v. 1.20 terminated
  155.         after file section break in concatenated interrup.lst file compilation,
  156.         and it could scramble extended register information.
  157.   v. 1.22 - 1998-11-22:
  158.     5 digits in table numbers. The major part of this fix was written by
  159.     Michael Hall <mjhall3@hotmail.com> - thank you.
  160.     Default extension .LST or .A, .B, ... for type 2 supplementary files.
  161. }
  162.  
  163. const
  164.   progName  = 'INT2WHLP';
  165.   progVers  = '1.22';
  166.   hfName    = 'INTWIN'; { helpfile name }
  167.   copyright = 'Copyright (C) 1994-1998 by Christian Müller-Planitz and Bent Lynggaard';
  168.   e_mail    = '"cmp@cs.utah.edu"';
  169.     { e-mail address in Intro/Explain windows }
  170.   e_mailCredits = '"cmp@cs.utah.edu"';
  171.     { e-mail address in the Credits window }
  172.   e_mailCredits2 = '"bent.lynggaard@risoe.dk"';
  173.     { e-mail address in the Credits window, coauthor }
  174.  
  175.   { the strings ack01 ... are displayed in the Credits window }
  176.  
  177.   { thanks to (excuse the format): }
  178.   ack01 = '\par{\b Michael Hall} "mjhall3@hotmail.com" for fix for 5 digits in table numbers';
  179. (* The following line is a template for an entry:
  180.   '\par{\b <name>} <reason for the entry>';
  181. *)
  182.   ack02 = '';
  183.   ack03 = '';
  184.   ack04 = '';
  185.   ack05 = '';
  186.   {if extended, update procedure "Credits"}
  187.  
  188.   {"errorlevel" constants:}
  189.   aliasErr    = 241; (* alias not found, or table exceeded *)
  190.   fileErr    = 242; (* cannot open file *)
  191.   formatErr    = 243; (* table exceeded, or fatal error in input file *)
  192.   paramErr    = 244; (* error in program parameter *)
  193.   rtfErr    = 245; (* unable to open output file *)
  194.   userErr    = 240; (* terminated by user *)
  195.  
  196. {$I INT2WHLP.INC }
  197.  
  198.   Procedure NewHlpPage(VAR F : Text; S, ID, BrowseID : String; Classification : Char);
  199.     label
  200.       deleteDone, insertKey;
  201.     type
  202.       intRec = record (* used for fast test and transfer of string *)
  203.     ln: byte;    (* string length *)
  204.     l: longint;  (* 'INT ' *)
  205.     n: word;     (* 'nn' *)
  206.     c7: char;    (* ' ' *)
  207.     l2: longint; (* 'ahal' or 'List' *)
  208.     c12: char;   (* ' ' *)
  209.     w: word;     (* '- ' *)
  210.       end; (* record intRec *)
  211.       nnRec = record ln: byte; w: word; (* for 'nn' *) end;
  212.       ahalRec = record ln: byte; l: longint; (* for 'ahal' *) end;
  213.     const
  214.       linebreak = #13#10'\par\tab';
  215.       intC = ord('I')+ord('N')*$100+ord('T')*$10000+ord(' ')*$1000000;
  216.       listC = ord('L')+ord('i')*$100+ord('s')*$10000+ord('t')*$1000000;
  217.       sepC = ord('-')+ord(' ')*$100;
  218.       int:  string[3] = 'nn';   (* preset length to 2, never changed *)
  219.     VAR
  220.       intR: nnRec absolute int; (* type cast *)
  221.       p,q : Word;
  222.       func: string[5];
  223.       funcR: ahalRec absolute func; (* type cast *)
  224.       ss: string;
  225.       ssR: intRec absolute ss;
  226.  
  227.     Procedure FootNote(Note: Char; ID : String);
  228.       begin
  229.     writeln(F, '{', Note,'}{\footnote ',Note,' ', ID, '}');
  230.       end;
  231.  
  232.     procedure insertInt;
  233.       begin
  234.     insert('INT '+int+equStr+func+';'+int+' '+func+';',ss,11);
  235.       (* "INT nn Ar = XXxx;nn XXxx;"  (XXxx = ahal, ah, or --al) *)
  236.     if equStr[3]='L' then delete(ss,21+equBlanks,2);
  237.       (* "--" from AL = --al *)
  238.     insert(copy(ss,18,6+equBlanks+2*ord(equStr[3]='X')),ss,11);
  239.       (* "Ar = XXxx;" *)
  240.       end; (* procedure insertInt in NewHlpPage *)
  241.     procedure insertSecReg(p, l: word);
  242.     (* duplicates part of SS and inserts secondary register *)
  243.       begin
  244.     insert(copy(ss,p,l),ss,p); (* duplicate *)
  245.     insert(secReg,ss,p+l+l-1); (* SXnnnn *)
  246.     insert(secReg,ss,p+l+p-5);
  247.     insert(equStr2,ss,p+l+p-2); (* SX = nnnn *)
  248.     insert(copy(secReg,2,7)+';',ss,p);   (* SXnnnn; *)
  249.     insert(equStr2,ss,p+2);    (* SX = nnnn; *)
  250.       end; (* procedure insertSecReg in NewHlpPage *)
  251.  
  252.     begin
  253.       PageRTF(F); (* insert '\page' if appropriate *)
  254.       writeln(F, '\pard\keepn\li'+indent+'\fi-'+indent);
  255.       FootNote('#', ID);
  256.       if S<>'' then FootNote('$', S);
  257.       if BrowseID<>'' then FootNote('+', BrowseID);
  258.       if (Classification <> nullClassification) then begin
  259.     ss:=s;
  260.     if Classification=titleOnlyClassification then goto insertKey;
  261.     if (ssR.l=intC) AND (ssR.c7=' ') then begin
  262.       if (length(ss)>14) AND (ssR.c12=' ') AND (ssR.w=sepC) then begin
  263.         (* insert highlight in s *)
  264.         insert('}}',s,7);
  265.         insert('{'+highlightInt+'{',s,1);
  266.           (* 2nd '{' terminates attribute, a ' ' distorts if attrib. is empty *)
  267.         (* insert tiny, short, and full form of INT *)
  268.         intR.w:=ssR.n;   (* length of "int" is preset to 2 *)
  269.         (* same as "int:=copy(ss,5,2);": nn from INT nn ahal - xxxx ... *)
  270.         funcR.l:=ssR.l2;
  271.         funcR.ln:=4;     (* func = 'ahal' *)
  272.         ss[7]:=';';      (* INT nn;ahal - xxxx ... *)
  273.         ss[8]:=int[1];
  274.         ss[9]:=int[2];
  275.         ss[10]:=';';     (* INT nn;nn;l - xxxx ... *)
  276.         delete(ss,11,4); (* INT nn;nn;xxxx ... *)
  277.         if func<>'----' then begin
  278.           if func[3]='-' then begin equStr[3]:='H'; func[0]:=#2; end
  279.           else if func[1]='-' then equStr[3]:='L'
  280.           else equStr[3]:='X';
  281.           insertInt;
  282.     (* INT nn;nn;AX = ahal;INT nn AX = ahal;nn ahal;xxxx ... or
  283.        INT nn;nn;AH = ah;INT nn AH = ah;nn ah;xxxx ... or
  284.        INT nn;nn;AL = al;INT nn AL = al;nn --al;xxxx ...
  285.     *)
  286.           if equStr[3]='H'then begin
  287.         insert(copy(ss,29+equBlanks+equBlanks,6)+'--',
  288.           ss,35+equBlanks+equBlanks);
  289.         insert('AX'+equStr2+copy(ss,39+equBlanks+equBlanks,5),
  290.           ss,44+equBlanks+equBlanks);
  291. (* INT nn;nn;AH = ah;INT nn AH = ah;nn ah;nn ah--;AX = ah--;xxxx ... *)
  292.           end; (* equStr[3]='H' *)
  293.           (* duplicate INT nn Ar = ... and insert secondary register
  294.          if appropriate.
  295.           *)
  296.           if secReg<>'' then case equStr[3] of
  297.         'X': insertSecReg(19+equBlanks, 23+equBlanks);
  298.         'H': insertSecReg(17+equBlanks, 19+equBlanks);
  299.         else insertSecReg(17+equBlanks, 21+equBlanks);
  300.           end; (* if secReg<>'' then case equStr[3] of *)
  301.           if equStr[3]='X' then begin (* insert also the AH values *)
  302.         equStr[3]:='H';
  303.         func[0]:=#2;
  304.         insertInt;
  305. (* INT nn;nn;AH = ah;INT nn AH = ah;nn ah;AX = ahal;INT nn AX = ahal;nn ahal;xxxx ... *)
  306.           end; (* if equStr[3]='X' *)
  307.         end (* if func<>'----' *)
  308.         else if secReg<>'' then insertSecReg(1, 10);
  309.         if NOT longKeys then repeat
  310.         (* disable long keys by deleting them. It is not very efficient
  311.            to insert search keys and then delete them again, however,
  312.            this was introduced at a late state due to restrictions in
  313.            WinHelp v. 4.00, and implemented the easy way. The long and
  314.                short formats in the preceding code are so integrated that
  315.                it would take hours to write a more efficient implementation.
  316.         *)
  317.           p:=pos('INT ',ss);
  318.           if p=0 then goto deleteDone;
  319.           q:=p+5;
  320.           while ss[q]<>';' do inc(q);
  321.           delete(ss,p,succ(q-p));
  322.         until false;
  323.     deleteDone:
  324.       end (* if length(ss)>14 ... *)
  325.       else if (length(s)=11) and (ssR.l2=listC) then begin
  326.         insert(copy(ss,1,6)+';',ss,1); (* INT nn;INT nn List *)
  327.         insert(copy(ss,5,3),ss,8); (* INT nn;nn;INT nn List *)
  328.       end; (* else if ... *)
  329.     end; (* if (ssR.l=intC) ... *)
  330.     if Classification=tableClassification then begin
  331.       delete(ss,1,8); (* 'II SUBF ' *)
  332.       footnote(tableKWT,'#'+currentTable);
  333.       if highestTableNumber<currentTable then highestTableNumber:=currentTable;
  334.     end (* if Classification=tableClassification *)
  335.     else repeat
  336.       p := POS(' - ', ss);
  337.       if p <> 0 then
  338.         begin
  339.           ss[p] := ';';
  340.           delete(ss,succ(p),2);
  341.         end;
  342.     until p=0;
  343.     if (Classification <> InvalidClassification)
  344.         AND (Classification > ' ') then begin
  345.       if categoryKeyStrings[Classification]^<>'' then begin
  346.         (* check for duplicate before inserting *)
  347.         p:=pos(categoryKeyStrings[Classification]^,ss);
  348.         q:=length(categoryKeyStrings[Classification]^);
  349.         if (p=0) OR ((p+q<>length(ss)) AND (ss[p+q]<>';')) then
  350.           insert(categoryKeyStrings[Classification]^+';',ss,1);
  351.       end; (* if categoryKeyStrings[Classification]^<>'' *)
  352.       if (Classification<'A') OR (Classification>'Z') then
  353.         insert(Classification+';',ss,1)
  354.       else insert(Classification+'!;',ss,1);
  355.     end; (* if (Classification<>InvalidClassification) ... *)
  356.       insertKey:
  357.     FootNote('K', SS);
  358.       end; (* if (Classification<>nullClassification) *)
  359.  
  360.       write(F, '{\f0'+headerAttrib,headerSize,' ');
  361.       if classification=specialClassification then write(F, indexHeader);
  362.       writeln(F, S,'}');
  363.       writeln(F, '\par\pard\keep');
  364.     end;
  365.  
  366.   Procedure AddTopic(VAR F: Text; ST, S, ID: String);
  367.   { print: ST as a string (normally "\par " for new line), S as a hotspot,
  368.     ID as the corresponding jump address or macro.
  369.   }
  370.     const sp: string[7] = '       ';
  371.     var p: integer;
  372.     begin
  373.       repeat
  374.     (* detab S, otherwise the string cannot be selected with the cursor
  375.        in a tab position.
  376.     *)
  377.     p:=pos(#9,S);
  378.     if p<>0 then begin S[p]:=' '; sp[0]:=char(7-(pred(p) AND 7)); insert(sp,S,p); end;
  379.       (* inserts 7..0 spaces for p = 1..8, 9..16 etc., total 8..1 spaces *)
  380.       until p=0;
  381.       writeln(F, ST,'{\uldb ', S, '}{\v ', ID, '}');
  382.     end;
  383.  
  384.   Procedure CheckKeyWords(VAR s : STring);
  385.     CONST KeyWords = 11;
  386.     CONST Keys : Array[1..KeyWords] of String[10] = ('Desc:', 'Notes:',
  387.       'Note:', 'Warning:', 'Index:', 'SeeAlso:', 'Return:', 'BUG:', 'BUGS:',
  388.       'Program:', 'Range:');
  389.     CONST IStr = '{\b ';
  390.     VAR q,p : Integer;
  391.  
  392.     begin
  393.       if length(s)<251 then for q:= 1 to KeyWords do begin
  394.     p := POS(Keys[q], S);
  395.     if p <> 0 then begin
  396.       insert(IStr, S, p);
  397.       insert('}', S, p+Length(Keys[q]) + Length(IStr));
  398.       exit;
  399.     end;
  400.       end;
  401.     end;
  402.  
  403.   Function GetSpecialNote(Note : Char)  : String;
  404.     begin
  405.       if flagStrings[Note]^='' then GetSpecialNote:='<unknown note in header>'
  406.       else GetSpecialNote:=flagStrings[Note]^;
  407.     end;
  408.  
  409. procedure insertQueued;
  410.   var i,j: word;
  411.   begin
  412.     if (indexColumns>1) OR (queuedEntry='') then exit;
  413.     val('$'+lastSection,i,j);
  414.     if singlesInMain AND (INTcounts[i]=1) then
  415.       AddTopic(IndexFile, nl, queuedEntry, lastSection+'_1')
  416.     else AddTopic(IndexFile, nl, title, lastSection+'_0');
  417.     queuedEntry:='';
  418.   end; (* procedure insertQueued *)
  419.  
  420. function inArray(n: integer; var arr: tableArray; var top: integer): boolean;
  421. (* returns true if n is in arr, else false *)
  422.   var i: integer;
  423.   begin
  424.     i:=1;
  425.     while (i<=top) AND (arr[i]<>n) do inc(i);
  426.     inArray:=i<=top;
  427.   end; (* function inArray *)
  428.  
  429. procedure toArray(n: integer; var arr: tableArray; var top: integer);
  430. (* inserts n in arr if not already present *)
  431.   begin
  432.     if inArray(n, arr, top) then exit;
  433.     if top=tableArraySize then errorExit('Table array exceeded',formatErr);
  434.     inc(top);
  435.     arr[top]:=n;
  436.   end; (* procedure toArray *)
  437.  
  438. Function ProcessIntList(FName : PathStr) : Boolean;
  439.   LABEL STOP, error_Exit, endOfLoop, table, fobi, noTable;
  440.   type
  441.     kind = (firstPart,inOverview,inFlags,inCategories,inKeys,
  442.       inFileBreakSection,pastTest);
  443.     tableId = array[1..8] of char;
  444.     sRec = record
  445.       l: byte; (* length *)
  446.       w: word; (* with '(T' *)
  447.       d: longint; (* with 'able' *)
  448.       c1: char; (* ' ' *)
  449.       ti: tableId; (* digits + ')' *)
  450.     end; (* record sRec *)
  451.     castRec = record
  452.       l: byte;
  453.       case byte of
  454.     1: (w: word);
  455.     2: (d: longint);
  456.     3: (c: char (* space *); r: word; rv: longint);
  457.     end; (* record castRec *)
  458.     dividerRec = record
  459.       s: string[8];    (* '--------' *)
  460.       cat: char;    (* category *)
  461.       c: char;    (* '-' *)
  462.       w: word;    (* Interrupt number, 2 hex digits *)
  463.       d: longint;    (* sub function, 4 hex digits or '-' *)
  464.       r: word;    (* secondary register name, two letters or '--' *)
  465.       rv: longint;    (* sec. reg. value, 4 hex digits or '-' *)
  466.     end; (* record dividerRec *)
  467.   const
  468.     INTno:     integer = 0;
  469.     bufferString: string = ''; (* transfers part of split string *)
  470.     ta = ord('(')+ord('T')*$100; (* (Table nnnnn) *)
  471.     able = ord('a')+ord('b')*$100+ord('l')*$10000+ord('e')*$1000000;
  472.     fo = ord('F')+ord('o')*$100; (* Format of ... *)
  473.     bi = ord('B')+ord('i')*$100; (* Bitfields for ... *)
  474.     Section: String[3] = '--'; (* initialize to length 2 *)
  475.     SubFunc: String[5] = '----'; (* length 4 *)
  476.     allMessages: boolean = false;
  477.  
  478.   VAR
  479.       tP:          ^tableID;
  480.       hLineP,tLineP : ^string; (* pointers to header and (Table) lines *)
  481.       p,q        : integer;
  482.       curTab     : integer;
  483.       lineCount  : word; (* for error report *)
  484.       NewSection : Boolean;
  485.       Classification,c      : Char;
  486.       current    : kind;
  487.       inTable    : boolean;
  488.       table_Id   : String[7];
  489.       tableTitle : String[119];
  490.       s          : String;
  491.       SpecialNote : String;
  492.       sR         : sRec absolute s; (* for type cast *)
  493.       sectionR   : castRec absolute Section;
  494.       subFuncR   : castRec absolute SubFunc;
  495.       secRegR    : castRec absolute secReg;
  496.       dR         : dividerRec absolute s;
  497.       F1         : Text;
  498.  
  499.   function isNumber(var ti: tableId): integer;
  500.   (* returns the table number, or negative value if illegal number *)
  501.     var i,res: integer;
  502.     begin
  503.       res:=0;
  504.       for i:=1 to tableDigits do case ti[i] of
  505.     '0'..'9': res:=res*10+ord(ti[i])-ord('0');
  506.     else begin isNumber:=-1; exit; end;
  507.       end; (* for ... do case ... *)
  508.       isNumber:=res;
  509.     end; (* function isNumber in function ProcessIntList *)
  510.   procedure insertRef;
  511.     begin
  512.       if inTable then AddTopic(TabTopics,nl,'INT '+Section+' '+SubFunc, TopicStr+mainW)
  513.       else if current<>inFileBreakSection then
  514.     AddTopic(IntTopics,nl,copy(title,1,6),IntTopicStr);
  515.     end; (* procedure insertRef in function ProcessIntList *)
  516.   procedure wrSection; (* show progress *)
  517.     begin write(Section,#13); end;
  518.  
  519.   begin
  520.    {$I-}
  521.     assign(F1, InPath + FName);
  522.     reset(F1);
  523.    {$I+}
  524.     if IOResult <> 0 then begin
  525.       ProcessIntList := FALSE;
  526.       EXIT;
  527.     end;
  528.     writeln('Processing : ', InPath + FName);
  529.     wrSection;
  530.     readLine(F1, s);    { ignore copyright in 1st two lines }
  531.     readLine(F1, s);
  532.     lineCount:=2;
  533.     current:=inFileBreakSection;
  534.     inTable:=false;
  535.     SpecialNote := '';
  536.     while not(EOF(F1)) do begin
  537.       readLine(F1, s);
  538.       inc(lineCount);
  539.       NewSection := (s[1]= '-') and (Pos('--------', s) = 1);
  540.       if NewSection then begin
  541.     if inTable then insertRef;
  542.     for p:=1 to tabTop do begin
  543.       q:=tabArray[p];
  544.       if NOT inArray(q, refArray, refTop) then begin
  545.         str(1000000+Longint(q),table_Id); (* 1xxnnnn *)
  546.         delete(table_Id,1,7-tableDigits);  (* [n]nnnn  *)
  547.         AddTopic(intTopics,nl,'Table #'+table_Id,'t'+table_Id+tableW);
  548.         inc(insertCounter);
  549.       end; (* if NOT inArray() *)
  550.     end; (* for p:=1 *)
  551.     inTable:=false;
  552.     insertRef;
  553.     if tabTop>maxTabTop then maxTabTop:=tabTop;
  554.     tabTop:=0;
  555.     if refTop>maxRefTop then maxRefTop:=refTop;
  556.     refTop:=0;
  557.     Classification := s[9];
  558.     if Classification = '!' then begin
  559.       delete(s,1,12);
  560.       q:=0;
  561.       while (s[q] <> '-') and (q < Length(s)) do
  562.         Inc(q);
  563.       s[0] := chr(q-1);  { remove '-' chars at the end }
  564.       if s='OVERVIEW' then current:=inOverview
  565.       else if s='FLAGS' then current:=inFlags
  566.       else if s='CATEGORIES' then current:=inCategories
  567.       else if s='CATEGORYKEYS' then current:=inKeys
  568.       else if s='Section' then begin
  569.         current:=inFileBreakSection;
  570.         goto endOfLoop;
  571.       end (* else if s='Section' *)
  572.       else current:=firstPart;
  573.       (* Interrupt List release 41 does not include OVERVIEW
  574.          and CATEGORYKEYS as sections, but as separate files.
  575.          The program is prepared for this information being
  576.          parts of the List.
  577.       *)
  578.       if s = '' then s:= 'Note';
  579.       if EOF(F1)  then   { last line of document ?}
  580.         goto STOP;
  581.       inc(TopicNo);
  582.       str(TopicNo, TopicStr);
  583.       if lastSection > '-' then section:='--'; (* at end of list *)
  584.     end { if Classification = '!' }
  585.     else begin (* (Classification <> '!') *)
  586.       SectionR.w:=dR.w; (* chars 11..12 of divider line *)
  587.       SubFuncR.d:=dR.d; (* chars 13..16 of divider line *)
  588.       secRegR.r:=dR.r;  (* chars 17..18 of divider line *)
  589.       if secReg[2]='-' then secReg[0]:=#0
  590.       else begin
  591.         secRegR.rv:=dR.rv; (* chars 19..22 of divider line *)
  592.         if secReg[6]='-' then secReg[0]:=#5 else secReg[0]:=#7;
  593.       end; (* else *)
  594.           if section<>lastSection then begin
  595.         val('$'+section,INTno,q);
  596.         if q<>0 then begin
  597.           writeln('Cannot interpret interrupt number in line ',
  598.         lineCount,': "',section,'".');
  599.           goto error_Exit;
  600.         end; (* if q<>0 *)
  601.       end; (* if section<>lastSection *)
  602.       current:=pastTest;
  603.       readLine(F1, s);
  604.       inc(lineCount);
  605.       inc(INTcounts[INTno]);
  606.       str(INTcounts[INTno], TopicStr);
  607.       insert(section+'_',TopicStr,1);
  608. (* We could compare already here: "while aliasString=s do ..." if we want to
  609.    use the orginal interrupt header line to find aliases. However,
  610.      1. it is easier to identify the original position of an alias line,
  611.      2. it is easier to determine the alias sequense in the config. file,
  612.      3. it is easier to track the reason for a "not found" error, and
  613.      4. the chance for an alias line to be unique is higher
  614.    if we compare after the manipulation of the header line. Also, if we copy
  615.    from the INTWIN index rather than from the original list, the lines are
  616.    already manipulated.
  617. *)
  618.     while (s[8] <> '-') do begin { special flags in titel-line ? }
  619.       if s[8] <> ' ' then
  620.         SpecialNote:=SpecialNote+#13#10'\par '+GetSpecialNote(s[8]);
  621.       delete(s, 8, 1);
  622.     end;
  623.         Insert(subFunc+' ', S, 8);
  624.     while aliasString=S do begin
  625.       saveAlias(nextAliasPP,aliasId+TopicStr);
  626.       getNextAlias(aliasP,aliasId,aliasString);
  627.     end; (* while aliasString=S *)
  628.       end; { else (Classification<>'!') }
  629.       if LastSection <> Section then begin
  630.     if Classification = '!' then begin
  631.       if indexColumns=1 then insertQueued;
  632.       IntTopicStr:='N_'+TopicStr;
  633.       title:='Notes';
  634.       if (notesCount MOD indexColumns)=0 then write(IndexFile,'\par ')
  635.       else  write(IndexFile,'\tab ');
  636.       inc(notesCount);
  637.       writeln(IndexFile,'{\uldb Notes}{\v ',IntTopicStr,'}');
  638.     end (* if Classification = '!' *)
  639.     else begin (* (Classification <> '!') *)
  640.       if INTno<lastINTno then begin
  641.         (* we cannot tolerate inconsistent sorting in a
  642.            multi-column index.
  643.         *)
  644.         writeln('Inconsistent sorting in file ',FName,
  645.           ' line ',lineCount);
  646.         writeln('INT ',section,' appears after INT ',lastSection);
  647.         if indexColumns>1 then begin
  648.           wl('This can be tolerated only with a single column index.');
  649.    error_Exit:
  650.           errorExit('Please correct the file and try again.',fileErr);
  651.         end; (* if indexColumns>1 *)
  652.         wl(#7'It is recommended to correct the file.');
  653.       end; (* if INTno<lastINTno *)
  654.       wrSection;
  655.       IntTopicStr:=Section+'_0';
  656.       if indexColumns=1 then begin
  657.         insertQueued;
  658.         queuedEntry:=s;
  659.       end; (* if indexColumns=1 *)
  660.       title:=INTtitles[INTno]^;
  661.       if title='' then title:='INT '+Section;
  662.       lastINTno:=INTno;
  663.         end; (* else (Classification <> '!') *)
  664.     if backRef then AddTopic(SubIntFile,nl,'Interrupts','idInterrupts');
  665.       (* don't insert a backward reference the very first time *)
  666.     backRef:=true; (* but in all the rest *)
  667.     NewHlpPage(SubIntFile, title, IntTopicStr,'i:0', specialClassification);
  668.     if twoIndexes AND indexHeaders then
  669.       OutLn(IntFile,'\par '+title);
  670.     LastSection := Section;
  671.       end; { if LastSection <> Section }
  672.       if TopicNo=1 then c:=specialClassification
  673.     (* The initial Interrupt List section should cary the
  674.        indexHeader.
  675.     *)
  676.       else c:=Classification;
  677.       NewHlpPage(IntTopics, s, TopicStr,'l:0', c);
  678.       if SpecialNote <> '' then    begin
  679.     writeln(IntTopics, '{\cf0 ', SpecialNote, '}'#13#10'\par ');
  680.     SpecialNote := '';
  681.       end; { if SpecialNote <> '' }
  682.       OutLN(IntTopics, '{\cf0 Category: '+ Classification +
  683.     ' - ' + categoryStrings[Classification]^ + '}\par');
  684.       if Classification='!' then setTabs(IntTopics, 8, deciPoints, 10)
  685.     (* we will set tabs in the few Notes, but not in all the
  686.        INT entries.
  687.     *)
  688.       else if markKeys then OutLN(IntTopics,'{\b Inp.:}');
  689.       if twoIndexes then AddTopic(IntFile, indentIndex, s, TopicStr);
  690.       AddTopic(SubIntFile, nl, s, TopicStr);
  691.     end { if NewSection }
  692.     else begin { no new section }
  693.       case current of
  694.     pastTest: begin
  695.   { this paragraph is un-indented to gain space for code }
  696.   if markKeys then CheckKeyWords(s);
  697.   { check the first two characters and react on '(T'[able nnnn)],
  698.     'Fo'[rmat of ...] and 'Bi'[tfields for ...]
  699.   }
  700.   if tables then case sR.w of
  701.     ta: if (length(s)>=12) AND (sR.d=able) AND (sR.c1=' ')
  702.       AND (sR.ti[tableDigits+1]=')') AND (isNumber(sR.ti)>=0) then begin
  703.     hLineP:=@bufferString;
  704.     tLineP:=@s;
  705.   table:
  706.     if eof(F1) then begin
  707.       writeln('Unexpected end of file in table at INT ',Section,
  708.         ' Subfunc ',SubFunc);
  709.       wrSection;
  710.       goto Stop;
  711.     end; (* if eof(F1) *)
  712.     ReadLine(F1, bufferString); (* v. 1.19: rather than readln() *)
  713.     inc(lineCount);
  714.     p:=pos('(Table ',tLineP^);
  715.     if (p=0) OR  (length(tLineP^)<p+tableDigits+7) OR
  716.       (tLineP^[p+tableDigits+7]<>')') then begin
  717.   noTable:
  718.       inc(missingTableCounter);
  719.       if allMessages OR (missingTableCounter<=missingTableLimit) then begin
  720.         writeln('Missing "(Table nnnn)" in INT ',Section,
  721.           ' Subfunc ',SubFunc,' (line ',lineCount,'):');
  722.         writeln(pred(lineCount):5,s:succ(length(s)));
  723.         writeln(lineCount:5,bufferString:succ(length(bufferString)));
  724.         if missingTableCounter=missingTableLimit then begin
  725.           wl(#13#10'Several missing tables encountered. If '
  726.         +progName+' is used on release 58 or lower');
  727.           wl('of the List, it should be started with the program '
  728.         +'parameter -rXX where XX is');
  729.           wl('the release number, or with key releaseNo=XX in section '
  730.             +'[OPTIONS] of the');
  731.           wl('configuration file.');
  732.           write('s=stop; m=messages; else continue without messages: ');
  733.           ProcessTime:=ProcessTime-memL[$40:$6C];
  734.           p:=readKeyWd;
  735.           ProcessTime:=ProcessTime+memL[$40:$6C];
  736.         (* sets ProcessTime "pause" ticks later than original *)
  737.           if word(p)<$100 then writeln (* function key *)
  738.           else begin
  739.         writeln(char(p));
  740.         case upcase(char(p)) of
  741.           'S': errorExit('Terminated by user',userErr);
  742.           'M': allMessages:=true;
  743.         end; (* case upcase(char(p)) of *)
  744.           end; (* else *)
  745.         end; (* if missingTableCounter=missingTableLimit *)
  746.         wrSection;
  747.       end; (* if allMessages ... *)
  748.       insert(nl,bufferString,1); (* force newline *)
  749.     end (* if (p=0) ... *)
  750.     else begin
  751.       tP:=@tLineP^[p+7];
  752.       curTab:=isNumber(tP^);
  753.       if curTab<0 then goto noTable;
  754.       toArray(curTab, tabArray, tabTop);
  755.       currentTable:=copy(tP^,1,tableDigits);
  756.       table_Id:='t'+currentTable;
  757.       if inTable then insertRef;
  758.       inTable:=true;
  759.       tableTitle:=Section+' '+SubFunc+' '+hLineP^;
  760.       while tableAliasString=tableTitle do begin
  761.         saveAlias(nextAliasPP,tableAliasId+table_id);
  762.         getNextAlias(tableAliasP,tableAliasId,tableAliasString);
  763.       end; (* while ... *)
  764.       NewHlpPage(TabTopics, tableTitle, table_Id,'t:0', tableClassification);
  765.       if tableWindow then begin
  766.         AddTopic(TabTopics,nl,'Copy to Main',table_Id+mainW);
  767.         OutLn(TabTopics,'');
  768.       end; (* if tableWindow *)
  769.       if sR.w=ta then begin (* bold Table nnnnn *)
  770.         s[1]:='{';             (* substitutes '(' *)
  771.         s[tableDigits+8]:='}'; (*   and ')'       *)
  772.         insert('\b ',s,2);
  773.       end (* if sR.w=ta *)
  774.       else begin
  775.         writeln(TabTopics,'\par {\b Table ',currentTable,'}');
  776.         bufferString[0]:=char(pred(p)); (* delete '(Table nnnn)' *)
  777.       end; (* else *)
  778.       AddTopic(TableFile,nl+currentTable+'  ',tableTitle,table_Id);
  779.     end; (* else *)
  780.     end; (* case ta *)
  781.     fo: if pos('Format of ',s)=1 then begin
  782.   fobi:
  783.       hLineP:=@s;
  784.       tLineP:=@bufferString;
  785.       goto table;
  786.     end; (* case fo *)
  787.     bi: if pos('Bitfields for ',s)=1 then goto fobi;
  788.     else begin
  789.       p:=length(s)-tableDigits;
  790.       for q:=p downto 1 do begin
  791.     if (s[q]='#') AND ((q=p) OR (s[q+tableDigits+1]<'0') OR
  792.         (s[q+tableDigits+1]>'9')) then begin
  793.       tP:=@s[q+1];
  794.       curTab:=isNumber(tP^);
  795.       if curTab>=0 then begin
  796.         toArray(curTab, refArray, refTop);
  797.         insert('}{\v t'+copy(tP^,1,tableDigits)+tableW+'}', S, q+tableDigits+1);
  798.         insert('{\uldb ', S, q);
  799.         if (length(s)-q>150) AND (q>20) then begin
  800.           (* we must ensure keeping length(S)<256 *)
  801.           bufferString:=copy(S, q, 255);
  802.           S[0]:=char(pred(q)); (* delete the copied part *)
  803.         end; (* if (length(s)-q>150)... *)
  804.       end; (* if curTab>=0 *)
  805.     end; (* if (s[q]='#')... *)
  806.       end; (* for q=p *)
  807.     end; (* else *)
  808.   end; (* case sR.w of *)
  809.   { indent again }
  810.       end; (* case pastTest *)
  811.       firstPart:    check1st(s);
  812.       inOverview:   getINTtitle(s,INTtitles);
  813.       inFlags:      scan(s,flagStrings);
  814.       inCategories: scan(s,categoryStrings);
  815.       inKeys:       scan(s,categoryKeyStrings);
  816.       inFileBreakSection: goto endOfLoop;
  817.     end; (* case current of *)
  818.     if inTable then OutLN(TabTopics, s) else OutLN(IntTopics, s);
  819.     if bufferString<>'' then begin
  820.       if inTable then OutLn(TabTopics, bufferString) (* with "newline" *)
  821.       else writeln(IntTopics, bufferString); (* no "newline" (\par ) *)
  822.       bufferString:='';
  823.     end; (* if bufferString<>'' *)
  824.       end; { else (no new section) }
  825.   endOfLoop:
  826.     end; { while not(EOF(F1)) }
  827.   STOP:
  828.     if inTable then insertRef;
  829.     inTable:=false;
  830.     insertRef;
  831.     close(F1);
  832.     ProcessIntList := TRUE;
  833.   end;
  834.  
  835. procedure missingFile(var fname: string);
  836.   var dir: dirstr; name: namestr; ext: extstr;
  837.   begin
  838.     fsplit(fname, dir, name, ext);
  839.     writeln(#7'Unable to open ', fname);
  840.     inc(warnings);
  841.     outln(indexFile,
  842.       'Unfortunately, file '+name+ext+' was unavailable at compile time.');
  843.   end; (* procedure missingFile() *)
  844.  
  845.   Procedure NewPage(VAR F: Text; Title : String);
  846.     VAR TopicStr : String;
  847.  
  848.       begin
  849.     Inc(TopicNo);
  850.     str(TopicNo, TopicStr);
  851.     AddTopic(IndexFile, nl, Title, TopicStr);
  852.     NewHlpPage(F, Title, TopicStr,'p:0', InvalidClassification);
  853.     setTabs(F, 8, deciPoints, 10);
  854.       end;
  855.  
  856.   Procedure ProcessPorts(FName : PathStr);
  857. (* Compile a file so that it gets its own index and is devided into sub topics.
  858.    If FName has no extension, .LST is assumed, and if a file with extension .LST
  859.    is not found .A and successive files .B, .C, ... are assumed ignoring the first
  860.    two lines of .B and the following files.
  861. *)
  862.     LABEL STOP, ok;
  863.     VAR i, kind    : integer;
  864.     s          : String;
  865.     dir        : dirStr;
  866.     name       : nameStr;
  867.     ext        : extStr;
  868.     NewSection : Boolean;
  869.     F1         : Text;
  870.  
  871.     begin
  872.       kind:=0;
  873.       defaultDir(FName,InPath);
  874.       fSplit(FName, dir, name, ext);
  875.       if ext='' then begin
  876.         ext:='.LST';
  877.         inc(kind);
  878.       end; (* if ext='' *)
  879.      {$I-}
  880.       assign(F1, dir+name+ext);
  881.       reset(F1);
  882.      {$I+}
  883.       if IOResult <> 0 then begin
  884.     if kind=1 then begin
  885.       ext:='.A';
  886.      {$I-}
  887.       assign(F1, dir+name+ext);
  888.       reset(F1);
  889.      {$I+}
  890.       if IOResult=0 then begin inc(kind); goto ok; end
  891.     end; (* if kind=1 *)
  892.     missingFile(FName);
  893.     EXIT;
  894.       end; (* if IOResult <> 0 *)
  895.     ok:
  896.       writeln('Processing : ', dir, name, ext);
  897.       if kind<3 then NewPage(IntTopics, name+' Note');
  898.       while not(EOF(F1)) do
  899.     begin
  900.       readLine(F1, s);
  901.       NewSection := (s[1]= '-') and (Pos('---------', s) <> 0);
  902.       if NewSection then
  903.         begin
  904.           readLine(F1, s);
  905.           if EOF(F1)  then   { last line of document ?}
  906.         goto STOP;
  907.           if s <> '' then                { why does this happend }
  908.         NewPage(IntTopics, s);
  909.         end
  910.       else
  911.         begin
  912.          CheckKeyWords(s);
  913.          OutLN(IntTopics, s);
  914.         end;
  915.     end;
  916.     STOP:
  917.       close(F1);
  918.       if (kind>1) AND (kind<=2+ord('Z')-ord('A')) then begin
  919.     inc(ext[2]);
  920.        {$I-}
  921.     assign(F1, dir+name+ext);
  922.     reset(F1);
  923.        {$I+}
  924.     if IOResult=0 then begin inc(kind); readln(F1); readln(F1); goto ok; end
  925.       (* ignore the first two lines of .B, .C, ... *)
  926.       end; (* if (kind>1)... *)
  927.     end;
  928.  
  929.   Procedure ProcessFile(FName : String; Title : String);
  930.     VAR s          : String;
  931.     F1, F2     : Text;
  932.         interrup1st: boolean;
  933.  
  934.     begin
  935.       defaultDir(FName,InPath);
  936.       interrup1st:=pos('INTERRUP.1ST',FName)<>0;
  937.      {$I-}
  938.       assign(F1, FName);
  939.       reset(F1);
  940.      {$I+}
  941.       if IOResult <> 0 then
  942.     begin
  943.       missingFile(FName);
  944.       if interrup1st then OutLn(IndexFile,
  945.         '{K}{\footnote K interrup.1st Contact Info}'#13#10+
  946.         'For contact information, try keyword '+
  947.         '{\uldb CONTACT_INFO}{\v !JumpKeyword(qchPath,"CONTACT_INFO")}.');
  948.       EXIT;
  949.     end;
  950.  
  951.       writeln('Processing : ', FName);
  952.       setTabs(IndexFile, 8, deciPoints, 10);
  953.  
  954.       while not(EOF(F1)) do
  955.     begin
  956.       readLine(F1, s);
  957.       if interrup1st AND (pos('-CONTACT_INFO-', s)<>0) then
  958.         insert(#13#10'{K}{\footnote K Ralf Brown}'
  959.               +#13#10'{K}{\footnote K Brown, Ralf}'
  960.               +#13#10'{K}{\footnote K CONTACT_INFO}'
  961.               (* the following is used as JumpKeyword() target from Credits *)
  962.               +#13#10'{K}{\footnote K interrup.1st Contact Info}'
  963.               +#13#10, s, 1);
  964.       OutLN(IndexFile, s);
  965.     end;
  966.  
  967.       close(F1);
  968.     end;
  969.  
  970.   Procedure Credits;
  971.     begin
  972.       OutLn(IndexFile,'');
  973.       AddTopic(IndexFile, nl, 'Credits', 'idCredits');
  974.       OutLn(IndexFile,'');
  975.       OutLn(IndexFile,compilationStr);
  976.       NewHlpPage(IndexFile, 'Credits', 'idCredits','m:1', InvalidClassification);
  977.       OutLn(IndexFile,'\pard{\f0'+headerSize+
  978.     '\qc\par Interrupt List (c) by {\b Ralf Brown}'#13#10 { \qc=centered }
  979.         +'{' + header2ndSize + '\par (See '
  980.         +'{\uldb Contact Info in interrup.1st}'
  981.         +'{\v !JumpKeyword(qchPath,"interrup.1st Contact Info")})}\par');
  982.       OutLn(IndexFile,'\par This list was converted from the released ASCII file'#13#10
  983.             + '\par to the Windows Help-Format by \par\par'#13#10
  984.             + '\par {\b Christian M\''81ller-Planitz}'
  985.                     + '{' + header2ndSize + '\par ' + e_mailCredits + '}'
  986.             + '\par and'
  987.                     + '\par {\b Bent Lynggaard}'+header2ndSize);
  988.       OutLn(IndexFile,e_mailCredits2);
  989. (* an alternative format of the last few lines:
  990.             + '\par {\b Christian M\''81ller-Planitz}'
  991.             + '   and   {\b Bent Lynggaard}'+header2ndSize);
  992.       OutLn(IndexFile,e_mailCredits + '  and  ' + e_mailCredits2);}
  993. *)
  994.       if ack01<>'' then begin
  995.     writeIndex('\par\par Thanks to:');
  996.     writeIndex(ack01);
  997.     writeIndex(ack02);
  998.     writeIndex(ack03);
  999.     writeIndex(ack04);
  1000.     writeIndex(ack05);
  1001.       end; (* if ack01<>'' *)
  1002.       writeIndex('\par}');
  1003.     end;
  1004.  
  1005. procedure processTopics(n: integer);
  1006. (* inserts references to n topics in the CONTENTS main index *)
  1007.   var i: integer; w: string[13]; title,id: string[39];
  1008.   begin
  1009.     for i:=1 to n do begin
  1010.       str(i,w);
  1011.       insert('WINDOW ',w,1);
  1012.       title:='';
  1013.       profileString(w,'title',title,pred(sizeOf(title)));
  1014.       id:='';
  1015.       profileString(w,'id',id,pred(sizeOf(id)));
  1016.       if (title<>'') AND (id<>'') then AddTopic(IndexFile,nl,title,id);
  1017.     end; (* for i:=1 *)
  1018.   end; (* procedure processTopics *)
  1019.  
  1020. procedure processPages(n: integer);
  1021. (* processes n "windows" as defined in the configuration file *)
  1022.   var
  1023.     i,j,wType,files,fType: integer;
  1024.     w: string[13];
  1025.     f: string[17];
  1026.     id: string[17];
  1027.     fId,chain: string[21];
  1028.     title,fTitle: string[39];
  1029.     fileName: pathStr;
  1030.   begin
  1031.     for i:=1 to n do begin
  1032.       str(i,w);
  1033.       insert('WINDOW ',w,1);
  1034.       title:='';
  1035.       profileString(w,'title',title,pred(sizeOf(title)));
  1036.       id:='';
  1037.       profileString(w,'id',id,pred(sizeOf(id)));
  1038.       if id<>'' then begin
  1039.     wType:=1;
  1040.     profileInt(w,'type',wType);
  1041.     files:=1;
  1042.     profileInt(w,'files',files);
  1043.     case wType of
  1044.       1: NewHlpPage(IndexFile,title,id,'f:0',InvalidClassification);
  1045.         (* Single entry windows *)
  1046.       2: NewHlpPage(IndexFile,title,id,'m:9',InvalidClassification);
  1047.         (* Multi entries windows *)
  1048.       3: ; (* nop *)   (* Windows with own contents list *)
  1049.     end; (* case wType of *)
  1050.     for j:=1 to files do begin
  1051.       str(j,f);
  1052.       insert('file ',f,1);
  1053.       fileName:='';
  1054.       profileString(w,f,fileName,pred(sizeOf(fileName)));
  1055.       if fileName<>'' then begin
  1056.         fType:=wType;
  1057.         profileInt(w,f+' type',fType);
  1058.         case fType of
  1059.           1: ProcessFile(fileName,title);
  1060.           2: ProcessPorts(fileName);
  1061.           3: begin
  1062.         (* the RTF file is expecte to be in:
  1063.              a. the current directory.
  1064.              b. the program's home directory
  1065.            if no drive or root is specified.
  1066.         *)
  1067.         if ((length(fileName)<2) OR (fileName[2]<>':'))
  1068.           AND (fileName[1]<>'\') AND (fileName[1]<>'.') then begin
  1069.           if exist(filename) OR NOT exist(homeDir+filename) then
  1070.             insert(currentDir,filename,1)
  1071.           else insert(homeDir,filename,1);
  1072.         end; (* if (fileName[2]<':'... *)
  1073.         fileName:=fExpand(fileName);
  1074.         if NOT exist(fileName) then begin
  1075.           writeln(#7'File ',fileName,' not found, copy to ',currentDir);
  1076.                   inc(warnings);
  1077.                 end; (* if NOT exist(filename) *)
  1078.         writeln(HPJ,fileName); (* include the file name *)
  1079.           end;
  1080.           4: begin (* ASCII file in multi file entry *)
  1081.         str(j,fTitle);
  1082.         str(j,fId);
  1083.         insert(title+' - ',fTitle,1);
  1084.         insert(id+'_',fId,1);
  1085.         chain:=id+':5';
  1086.         profileString(w,f+' title',fTitle,pred(sizeOf(fTitle)));
  1087.         profileString(w,f+' id',fId,pred(sizeOf(fId)));
  1088.         profileString(w,f+' chain',chain,pred(sizeOf(chain)));
  1089.         NewHlpPage(IndexFile,fTitle,fId,chain,InvalidClassification);
  1090.         defaultDir(fileName,currentDir);
  1091.         ProcessFile(fileName,fTitle);
  1092.           end; (* case 4 *)
  1093.         end; (* case fType of *)
  1094.       end (* if fileName<>'' *)
  1095.       else begin
  1096.         writeln(#7'Missing file name for [',w,'] ',f);
  1097.         inc(warnings);
  1098.       end; (* else *)
  1099.     end; (* for j:=1 *)
  1100.       end (* if (title<>'') ... *)
  1101.       else begin
  1102.     writeln(#7'Missing identifier in ',w);
  1103.     inc(warnings);
  1104.       end; (* else *)
  1105.     end; (* for i:=1 *)
  1106.   end; (* procedure processPages *)
  1107.  
  1108. procedure processFilter;
  1109.   var d: dirStr;
  1110.   begin
  1111.     PageRTF(IndexFile); (* insert '\page' if appropriate *)
  1112.     writeIndex('\pard');
  1113.     writeIndex('#{\footnote{#} idPartComp}');
  1114.     writeIndex('{\f0'+header2ndSize+' This compilation of the Interrupt List does '+#13#10
  1115.       +'not contain all the information in the List, see the '#13#10
  1116.       +'{\uldb INTERRUP.1ST File}{\v id1st} for the availability of the ');
  1117.     writeIndex('complete list.\par\par');
  1118.     writeIndex('See {\uldb Filter Method}{\v idFlt_meth} and '#13#10
  1119.       +'{\uldb Filter File}{\v idFlt_file} for details.\par}');
  1120.     d:=currentDir;
  1121.     if NOT exist('FLT_METH.RTF') then begin
  1122.       if exist(homeDir+'FLT_METH.RTF') then d:=homeDir
  1123.       else begin
  1124.     writeln(#7'File FLT_METH.RTF not found, copy to ',d);
  1125.     inc(warnings);
  1126.       end; (* else *)
  1127.     end; (* if NOT exist() *)
  1128.     writeln(HPJ,d,'FLT_METH.RTF');
  1129.     NewHlpPage(IndexFile, 'Filter File', 'idFlt_file','flt:1', invalidClassification);
  1130.     processFile(filterFileName,'Filter File');
  1131.   end; (* procedure processFilter *)
  1132.  
  1133. procedure readCategoryKeys;
  1134. (* Opens file CATEGORY.KEY if available, and reads definitions to
  1135.    categoryKeyStrings. Definitions are of the type
  1136.       A - definition A, B - definition B,
  1137.    The definitions are inserted as search keys for the appropriate
  1138.    categories. Note that more than one keyword per entry is accepted,
  1139.    separated by a semicolon, e.g. " c - cachers;spoolers,".
  1140.  
  1141.    Reads also title file OVERVIEW.LST.
  1142.  
  1143.    CATEGORY.KEY and OVERVIEW.LST are separate files in Interrupt List
  1144.    release 41+.
  1145. *)
  1146.   var t: text; s: string;
  1147.   begin
  1148. (*$I-*)
  1149.     assign(t,InPath+'category.key');
  1150.     reset(t);
  1151. (*$I+*)
  1152.     if IOresult<>0 then writeln('Unable to open ',InPath,'CATEGORY.KEY')
  1153.     else begin
  1154.       while NOT eof(t) do begin readln(t,s); scan(s,categoryKeyStrings); end;
  1155.       close(t);
  1156.     end; (* else *)
  1157. (*$I-*)
  1158.     assign(t,InPath+'overview.lst');
  1159.     reset(t);
  1160. (*$I+*)
  1161.     if IOresult<>0 then writeln('Unable to open ',InPath,'OVERVIEW.LST')
  1162.     else begin
  1163.       while NOT eof(t) do begin readln(t,s); getINTtitle(s,INTtitles); end;
  1164.       close(t);
  1165.     end; (* else *)
  1166.   end; (* procedure readCategoryKeys *)
  1167.  
  1168. procedure INTsToIndex;
  1169.   var i,j,k,l: word; s: string[3];
  1170.   begin
  1171.     for k:=0 to pred(indexPages) do begin
  1172.       l:=k*indexRows*indexColumns;
  1173.       for i:=0 to pred(indexRows) do begin
  1174.     OutLn(IndexFile, '');
  1175.     for j:=0 to pred(indexColumns) do begin
  1176.       if INTcounts[l+i+j*16]<>0 then begin
  1177.         write(IndexFile,'{\uldb INT ',HEX(l+i+j*16));
  1178.         if indexColumns=4 then write(IndexFile,' List');
  1179.         write(IndexFile,'}{\v ',HEX(l+i+j*16),'_0}');
  1180.       end (* if INTcounts[]<>0 *)
  1181.       else if indexColumns=4 then write(IndexFile,'\tab ');
  1182.       if j<pred(indexColumns) then write(IndexFile,'\tab ');
  1183.     end; (* for j:=0 *)
  1184.       end; (* for i:=0 *)
  1185.       if k<pred(indexPages) then OutLn(IndexFile, '');
  1186.     end; (* for k:=0 *)
  1187.   end; (* procedure INTsToIndex *)
  1188.  
  1189.   const
  1190.     windows: integer = 0;
  1191.  
  1192.   var
  1193.     i: integer;
  1194.     ch: char;
  1195.  
  1196.   begin
  1197.     Intro;
  1198.     if (paramStr(1)='?') OR (paramStr(1)='-?') OR (paramStr(1)='/?')
  1199.       then Explain; (* and exit *)
  1200.  
  1201.     fSplit(paramStr(0),homeDir,currentDir,currentDir);
  1202.       (* works only with DOS 3.30+ - currentDir is used as a dummy *)
  1203.     currentDir:=fExpand('.');
  1204.     if length(currentDir)>3 then begin
  1205.       inc(currentDir[0]);
  1206.       currentDir[length(currentDir)]:='\';
  1207.     end; (* if length()... *)
  1208.     interpretParameters;
  1209.     initializeArrays;
  1210.     nextAliasPP:=@firstAliasP;
  1211.  
  1212.     if InPath='' then begin
  1213.       write('Source directory: ');
  1214.       readln(InPath);
  1215.     end; (* if InPath='' *)
  1216.     if InPath<>'' then begin
  1217.       ch:=InPath[length(InPath)];
  1218.       if (ch<>':') AND (ch<>'\') then
  1219.     begin inc(InPath[0]); InPath[length(InPath)]:='\'; end;
  1220.     end; (* if InPath<>'' *)
  1221.  
  1222.     if OutPath='' then begin
  1223.       write('Dest. directory (has to be created in advance) : ');
  1224.       readln(OutPath);
  1225.     end; (* if OutPath='' *)
  1226.     if OutPath<>'' then begin
  1227.       ch:=OutPath[length(OutPath)];
  1228.       if (ch<>':') AND (ch<>'\') then
  1229.     begin inc(OutPath[0]); OutPath[length(OutPath)]:='\'; end;
  1230.     end; (* if OutPath<>'' *)
  1231.  
  1232.     ProcessTime:=memL[$40:$6C]; { timer ticks since midnight }
  1233.     findDateAndCopyright;
  1234.     CreateHPJ;
  1235.  
  1236.     OpenRTF(IndexFile, 'INDEX.RTF');
  1237.     NewHlpPage(IndexFile, 'Contents:', 'CONTENTS','m:2', specialClassification);
  1238.  
  1239.     readCategoryKeys; (* reads also titles *)
  1240.     OpenRTF(SubIntFile,'SUBINT.RTF');
  1241.     OpenRTF(IntTopics, 'INTTOPIC.RTF');
  1242.     if twoIndexes then OpenRTF(IntFile, 'INT.RTF');
  1243.  
  1244.     if twoIndexes then
  1245.       AddTopic(IndexFile, nl, 'Interrupt Index',
  1246.     '!IfThenElse(IsMark("Compressed_Index"), '
  1247.     +'`JumpId(qchPath,"idInterrupts")'', `JumpId(qchPath,"idIndex")'')')
  1248.     else AddTopic(IndexFile, nl, 'Interrupts', 'idInterrupts');
  1249.     if tables then AddTopic(IndexFile, nl, 'Tables', 'idTables');
  1250.     AddTopic(IndexFile, nl, 'FILELIST', '1');
  1251.     AddTopic(IndexFile, nl, 'INTERRUP.1ST File', 'id1st');
  1252.     if filtered then begin
  1253.       AddTopic(IndexFile, nl, 'Filter Method', 'idFlt_meth');
  1254.       AddTopic(IndexFile, nl, 'Filter File', 'idFlt_file');
  1255.     end; (* if filtered *)
  1256.  
  1257.     profileInt('WINDOWS','number',windows);
  1258.     processTopics(windows); (* insert Ports, Memory etc. in index *)
  1259.  
  1260.     Credits;
  1261.  
  1262.     if twoIndexes then begin
  1263.       NewHlpPage(IntFile, 'Interrupt Index', 'idIndex','m:3', specialClassification);
  1264.       AddTopic(IntFile, nl, 'Compress index',
  1265.     '!SaveMark("Compressed_Index");JumpId(qchPath,"idInterrupts")');
  1266.       { the program adds all following entries }
  1267.     end; (* if twoIndexes *)
  1268.     NewHlpPage(IndexFile, 'Interrupts', 'idInterrupts','m:4', specialClassification);
  1269.     if twoIndexes then begin
  1270.       AddTopic(IndexFile, nl, 'Expand index','!IfThen(IsMark("Compressed_Index"),'
  1271.     +' `DeleteMark("Compressed_Index")'');JumpId(qchPath,"idIndex")');
  1272.       OutLn(IndexFile, '');
  1273.       if indexColumns>1 then setTabs(IndexFile, succ(ord(indexColumns<=4))*8,
  1274.     deciPoints, pred(indexColumns));
  1275.     end; (* if twoIndexes *)
  1276.  
  1277.     if tables then begin
  1278.       OpenRTF(TableFile, 'TABLE.RTF');
  1279.       OpenRTF(TabTopics, 'TABTOPIC.RTF');
  1280.       NewHlpPage(TableFile,'Tables\f1'+fontSize+'\par\par Tab# INT Func Title',
  1281.     'idTables','m:5', invalidClassification);
  1282.       (* "Tab# INT Func Title" in normal text font and size *)
  1283.     end; (* if tables *)
  1284.  
  1285.     profileList('ALIAS',aliasP); (* read [ALIAS] section from config. file *)
  1286.     getNextAlias(aliasP,aliasId,aliasString); (* get the first one (if any) *)
  1287.     profileList('TABLEALIAS',tableAliasP);
  1288.     getNextAlias(tableAliasP,tableAliasId,tableAliasString);
  1289.  
  1290.     (* process either "interrup.lst" or "interrup.a".."interrup.?" *)
  1291.     if NOT ProcessIntList('interrup.lst') then begin
  1292.       ch := 'a';
  1293.       while ProcessIntList('interrup.'+ch) do inc(ch);
  1294.     end; (* if NOT ProcessIntList() *)
  1295.     if NOT longKeys then writeln(HPJ,'SHORTKEY.RTF');
  1296.       (* include short keyword help topic *)
  1297.     if tableKWT<>'K' then begin
  1298.       NewHlpPage(TableFile,'#Table Search','idTableSearch','ts:1',
  1299.     titleOnlyClassification);
  1300.       AddTopic(TableFile,nl,'Enter a table number','!SearchSecondaryKey'
  1301.     +'(hwndApp,qchPath,84,`IntWin Table'',`Enter a four digit table number 0001 - '
  1302.     +highestTableNumber+''',`#'',`'')');
  1303.     (* 84 is ord('T') *)
  1304.       writeln(TableFile,' (seckey.dll required, see details)');
  1305.       AddTopic(TableFile,nl,'Cancel','!back()');
  1306.       AddTopic(TableFile,nl,'Table Search Details','idTableDetails');
  1307.       writeln(HPJ,'TABLEKWT.RTF');
  1308.       (* include table keyword topic *)
  1309.     end; (* if tableKWT<>'K' *)
  1310.  
  1311.     if aliasString<>'' then begin
  1312.       writeln(#7'Alias string not found:'#13#10+'  "',aliasString,'"');
  1313.       inc(warnings);
  1314.       if aliasP<>NIL then
  1315.     wl('One or more alias strings not processed.');
  1316.     end; (* if aliasP<>NIL *)
  1317.     if tableAliasString<>'' then begin
  1318.       writeln(#7'Table alias string not found:'#13#10+'  "',
  1319.     tableAliasString,'"');
  1320.       inc(warnings);
  1321.       if tableAliasP<>NIL then
  1322.     wl('One or more table alias strings not processed.');
  1323.     end; (* if tableAliasP<>NIL *)
  1324.  
  1325.     if indexColumns=1 then insertQueued
  1326.     else INTsToIndex;
  1327.  
  1328.     NewHlpPage(IndexFile, 'INTERRUP.1ST File', 'id1st','f:0', invalidClassification);
  1329.     ProcessFile('interrup.1st', 'INTERRUP.1ST File');
  1330.     if filtered then processFilter;
  1331.  
  1332.     processPages(windows); (* process Ports, Memory etc. *)
  1333.  
  1334.     if firstAliasP<>NIL then begin
  1335.       writeln(HPJ,#13#10'[ALIAS]');
  1336.       processAliasList(firstAliasP);
  1337.     end; (* if (firstAliasP<>NIL)... *)
  1338.     if twoIndexes then closeRTF(IntFile);
  1339.     closeRTF(SubIntFile);
  1340.     closeRTF(IntTopics);
  1341.     if tables then begin
  1342.       closeRTF(TableFile);
  1343.       closeRTF(TabTopics);
  1344.     end; (* if tables *)
  1345.     closeRTF(IndexFile);
  1346.     close(HPJ);
  1347.     if missingTableCounter>=missingTableLimit then
  1348.       writeln(missingTableCounter,' missing tables encountered.');
  1349.     ProcessTime:=memL[$40:$6C]-ProcessTime;
  1350.     writeln('The processing took ',(ProcessTime*10+91) DIV 182,' seconds.');
  1351.       (* 18.2 clock ticks per second, rounded *)
  1352.     i:=(maxTabTop*100) DIV tableArraySize;
  1353.     if i>60 then writeln(i,'% table array usage.');
  1354.     i:=(maxRefTop*100) DIV tableArraySize;
  1355.     if i>60 then writeln(i,'% reference array usage.');
  1356.     if insertCounter<>0 then writeln('Inserted ',insertCounter,' table references.');
  1357.     if warnings<>0 then begin
  1358.       writeln('Issued ',warnings,' warning(s).');
  1359.       halt(1);
  1360.     end; (* if warnings<>0 *)
  1361.   end.
  1362.